;+
; NAME:
;     D2_LAMP_DEG
;
; PURPOSE:
;     Calculate and plot the effects of degredation of the internal
;     deuterium lamp.
;
; CATEGORY:
;     ACS/ANALYSIS
;
; CALLING SEQUENCE:
;     D2_LAMP_DEG
; 
; INPUTS:
;
; OPTIONAL INPUTS:
;      
; KEYWORD PARAMETERS:
;
; OUTPUTS:
;     plots.
;
; OPTIONAL OUTPUTS:
;
; COMMON BLOCKS:
;
; SIDE EFFECTS:
;
; RESTRICTIONS:
;
; PROCEDURE:
;
; EXAMPLE:
;
; MODIFICATION HISTORY:
;
;    Mon Apr 26 09:41:02 1999, William Jon McCann
;    <mccannwj@acs13.+hst.nasa.gov>
;
;		written.
;
;-

PRO d2_lamp_deg

   list = [4954,4962,4963,4964,4965,4966,4967]

   dark_begin = 4953
   dark_end   = 4968

   acs_read, dark_begin, header_dark1,  data_dark1, /KEEP
   acs_read, dark_end, header_dark2,  data_dark2, /KEEP
   
   dark1_exp_time = SXPAR( header_dark1, 'EXPTIME' )
   dark2_exp_time = SXPAR( header_dark2, 'EXPTIME' )
   dark1_tube_temp = SXPAR( header_dark1, 'SBCTEMP' )
   dark2_tube_temp = SXPAR( header_dark2, 'SBCTEMP' )

   dark1_rate = TOTAL( data_dark1 ) / DOUBLE(dark1_exp_time)
   dark2_rate = TOTAL( data_dark2 ) / DOUBLE(dark2_exp_time)

   dark1_temp_rate = dark1_rate / dark1_tube_temp
   dark2_temp_rate = dark2_rate / dark2_tube_temp

   avg_temp_rate = (dark1_temp_rate + dark2_temp_rate) / 2d

   PRINT, 'entry', 'filter', 'sbctemp', 'im-rate', 'darkrate', $
    'delta', 'seconds', FORMAT='(A5,1X,A9,1X,A8,1X,A8,1X,A8,1X,A8,1X,A8,1X,A)'
   PRINT, '_________________________________________________________________'

   times = MAKE_ARRAY( N_ELEMENTS( list ), /FLOAT )
   rates = MAKE_ARRAY( N_ELEMENTS( list ), /FLOAT )

   FOR i = 0, N_ELEMENTS(list)-1 DO BEGIN

      acs_read, list[i], header, data, /KEEP

      filter_name = SXPAR( header, 'FILTER3' )
      exp_time = SXPAR( header, 'EXPTIME' )
      tube_temp = SXPAR( header, 'SBCTEMP' )
      exp_start = SXPAR( header, 'EXPSTART' )
      exp_end = SXPAR( header, 'EXPEND' )

      dark_rate = avg_temp_rate * tube_temp

      image_rate = TOTAL( data ) / DOUBLE(exp_time)

      global_rate = image_rate - dark_rate

      IF (i EQ 0) THEN BEGIN
         time0 = exp_start
         rate0 = global_rate
      ENDIF

      rates[i] = global_rate

      delta_time = (exp_start - time0) * 24e * 3600e
      delta_rate = global_rate - rate0
      times[i] = delta_time
      PRINT, i, filter_name, tube_temp, image_rate, dark_rate, delta_rate, $
       delta_time, FORMAT='(I5,1X,A9,1X,F8.4,1X,F8.2,1X,F8.4,1X,F8.2,1X,G8.2)'
      
      header = ''
      data = 0
   ENDFOR 

   PLOT, times, rates, XSTYLE=3, YSTYLE=3, PSYM = 4, $
    XTITLE = 'Time (seconds)', YTITLE = 'Global count rate', $
    TITLE = 'Deuterium lamp degradation'

   fit_coeff = POLY_FIT( times, rates, 1, Yfit )

   OPLOT, times, Yfit, LINESTYLE = 2
   XYOUTS, .7, .90, /NORMAL, 'F(x) = A0 + A1 x'
   XYOUTS, .7, .85, /NORMAL, 'A0: ' + STRTRIM( fit_coeff[0], 2 )
   XYOUTS, .7, .80, /NORMAL, 'A1: ' + STRTRIM( fit_coeff[1], 2 )

   y_hour = fit_coeff[0] + fit_coeff[1] * 3600e

   XYOUTS, .7, .70, /NORMAL, 'F(3600s) = ' + STRTRIM( y_hour, 2 )
   percent_down = (1e - (y_hour / fit_coeff[0]) ) * 100e
   XYOUTS, .7, .65, /NORMAL, '  down: ' + STRTRIM( percent_down, 2 ) + '%'

END