pro psl,dummy,eps=eps

set_plot,'ps'
device,/landscape
if keyword_set(eps) then device,/encapsulated
end

pro psend,psfile,noprint=noprint,clobber=clobber
;
if !d.name ne 'SUN' then begin
  device,/close
  if n_elements(psfile) gt 0 then begin
    if keyword_set(clobber) then spawn,'mv -f idl.ps '+psfile $
                            else spawn,'mv idl.ps '+psfile
    if not keyword_set(noprint) then spawn,'lpr '+psfile
  endif else if not keyword_set(noprint) then spawn,'lpr idl.ps'
  device,/portrait
  set_plot,'X'
endif
;
end

PRO plot_monitor_all
   xr    =  [27.0,49.0]
   yr    =  [0.3,1.05]
   ;
   ;  predictions
   ;
   krmod = 0.790 + 0.0*xr
   xemod = 1.002 + 0.0*xr
   krcei = 0.100 * 0.7317 / 0.1329 + 0.0*xr
   xecei = 0.047 * 0.8452 / 0.0848 + 0.0*xr
   ;
   ;  read in monitor data
   ;
   readcol,'monitor_kr.dat',i1,i2,i3,s4,s5,f6,i7,f8,f9,tkr,i11,f12,$
    i13,f14,f15,i16,f17,i18,i19,i20,i21,i22,ratkr,eratkr,$
    format='I,I,I,A,A,F,I,F,F,D,I,F,I,F,F,I,F,I,I,I,I,I,F,F',$
    skipline=3
   readcol,'monitor_xe.dat',i1,i2,i3,s4,s5,f6,i7,f8,f9,txe,i11,f12,$
    i13,f14,f15,i16,f17,i18,i19,i20,i21,i22,ratxe,eratxe,$
    format='I,I,I,A,A,F,I,F,F,D,I,F,I,F,F,I,F,I,I,I,I,I,F,F',$
    skipline=3

  tkr = tkr - 51200.0
  txe = txe - 51200.0

;  FOR i = 0, n_elements(tkr)-1 DO print,tkr[i],ratkr[i],eratkr[i] 

  plot,tkr,ratkr,psym=4,xrange=xr,yrange=yr,$
   xstyle=1,ystyle=1,title='SBC Throughput monitor results',$
   xtitle='MJD - 51200',ytitle='I!DSBC!N/I!DPMT!N',$
   xcharsize=1.3,ycharsize=1.3
  oploterr,tkr,ratkr,eratkr,4
  oploterr,txe,ratxe,eratxe,5
  oplot,xr,krmod,linestyle=1,psym=0
  oplot,xr,xemod,linestyle=0,psym=0
  oplot,xr,krcei,linestyle=1,psym=0,thick=3
  oplot,xr,xecei,linestyle=0,psym=0,thick=3

  FOR i = 0, n_elements(xr)-1 DO print,xr[i],krmod[i],xemod[i]

END

PRO plot_monitor_kr
   xr       =  [27.0,53.0]
   yr       =  [0.3,1.05]
   ;
   ;  predictions
   ;
   krmod    = 0.790 + 0.0*xr
   krcei    = 0.100 * 0.7317 / 0.1329 + 0.0*xr
   ;
   ;  read in monitor data
   ;
   readcol,'monitor_kr.dat',i1,i2,i3,s4,s5,f6,i7,f8,f9,tkr,i11,f12,$
    i13,f14,f15,i16,f17,i18,i19,i20,i21,i22,ratkr,eratkr,$
    format='I,I,I,A,A,F,I,F,F,D,I,F,I,F,F,I,F,I,I,I,I,I,F,F',$
    skipline=3

   tkr = tkr - 51200.0
   ;
   ; plot the results
   ;
   plot,tkr,ratkr,psym=4,xrange=xr,yrange=yr,$
    xstyle=1,ystyle=1,title='SBC Throughput monitor results for Kr1236',$
    xtitle='MJD - 51200',ytitle='I!DSBC!N/I!DPMT!N',$
    xcharsize=1.3,ycharsize=1.3
   oploterr,tkr,ratkr,eratkr,4
   ;
   ; indicate model results and CEI specs
   oplot,xr,krmod,linestyle=1,psym=0
   oplot,xr,krcei,linestyle=0,psym=0,thick=3
   ;
   ; annotate model results and CEI specs
   xlabpos  = xr[0] + 0.9*(xr[1] - xr[0])
   ylabpos1 = krmod[0] + 0.015
   ylabpos2 = krcei[0] + 0.015
   lab1     = 'Synphot model prediction'
   lab2     = 'CEI spec. (10.0% @ 1216 Angstroms - opt. bench level)'
   xyouts,xlabpos,ylabpos1,lab1,alignment=1.0
   xyouts,xlabpos,ylabpos2,lab2,alignment=1.0
   ;
   ; calculate & print mean and variance
   rat_stats = moment(ratkr)
   err_stats = moment(eratkr)
   print,'Mean  SBC/PMT(Kr) = ',rat_stats[0]
   print,'sigma SBC/PMT(Kr) = ',sqrt(rat_stats[1])
   print,'mean err(SBC/PMT) = ',err_stats[0]
END

PRO plot_monitor_xe
   xr    =  [27.0,53.0]
   yr    =  [0.3,1.05]
   ;
   ;  predictions
   ;
   xemod = 1.002 + 0.0*xr
   xecei = 0.047 * 0.8452 / 0.0848 + 0.0*xr
   ;
   ;  read in monitor data
   ;
   readcol,'monitor_xe.dat',i1,i2,i3,s4,s5,f6,i7,f8,f9,txe,i11,f12,$
    i13,f14,f15,i16,f17,i18,i19,i20,i21,i22,ratxe,eratxe,$
    format='I,I,I,A,A,F,I,F,F,D,I,F,I,F,F,I,F,I,I,I,I,I,F,F',$
    skipline=3

   txe = txe - 51200.0
   ;
   ; plot the results
   ;
   plot,txe,ratxe,psym=5,xrange=xr,yrange=yr,$
    xstyle=1,ystyle=1,title='SBC Throughput monitor results for Xe1469',$
    xtitle='MJD - 51200',ytitle='I!DSBC!N/I!DPMT!N',$
    xcharsize=1.3,ycharsize=1.3
   oploterr,txe,ratxe,eratxe,5
   ;
   ; indicate model results and CEI specs
   oplot,xr,xemod,linestyle=1,psym=0
   oplot,xr,xecei,linestyle=0,psym=0,thick=3
   ;
   ; annotate model results and CEI specs
   xlabpos  = xr[0] + 0.9*(xr[1] - xr[0])
   ylabpos1 = xemod[0] + 0.015
   ylabpos2 = xecei[0] + 0.015
   lab1     = 'Synphot model prediction'
   lab2     = 'CEI spec. (4.8% @ 1500 Angstroms - opt. bench level)'
   xyouts,xlabpos,ylabpos1,lab1,alignment=1.0
   xyouts,xlabpos,ylabpos2,lab2,alignment=1.0
   ;
   ; calculate & print mean and variance
   rat_stats = moment(ratxe)
   err_stats = moment(eratxe)
   print,'Mean  SBC/PMT(Xe) = ',rat_stats[0]
   print,'sigma SBC/PMT(Xe) = ',sqrt(rat_stats[1])
   print,'mean err(SBC/PMT) = ',err_stats[0]
END

PRO plot_kr_vs_i
   ;
   ;  flag to plot all or just meb = 2 data.  0b for
   ;  just meb=2, 1b for all
   ;
   plotall  = 0b
   ;
   xr       =  [0.0, 0.25]
   yr       =  [0.3,1.05]
   ;
   ;  predictions
   ;
   krmod    = 0.790 + 0.0*xr
   krcei    = 0.100 * 0.7317 / 0.1329 + 0.0*xr
   ; 
   ; read in data
   ;
   readcol,'kr_vs_i.dat',i1,i2,meb,s4,s5,current,i7,f8,f9,txe,i11,f12,$
    i13,f14,f15,i16,f17,i18,i19,i20,i21,i22,ratkr,eratkr,$
    format='I,I,I,A,A,F,I,F,F,D,I,F,I,F,F,I,F,I,I,I,I,I,F,F',$
    skipline=3
   ;
   IF (plotall EQ 0b) THEN BEGIN 
      ;
      ; select only MEB = 2 data
      ;
      good    = where(meb EQ 2) 
      current = temporary(current[good])
      ratkr   = temporary(ratkr[good])
      eratkr  = temporary(eratkr[good])
      prlab   = 'Kr lamp current anomaly'
   ENDIF ELSE prlab = 'Kr lamp current anomaly (all data)'
   ;
   ; plot results
   ;
   plot,current,ratkr,psym=4,xrange=xr,yrange=yr,$
    xstyle=1,ystyle=1,title=prlab,$
    xtitle='I!DKr-lamp!N [Amp]',ytitle='I!DSBC!N/I!DPMT!N',$
    xcharsize=1.3,ycharsize=1.3
   oploterr,current,ratkr,eratkr,4
   ;
   ; indicate model results and CEI specs
   oplot,xr,krmod,linestyle=1,psym=0
   oplot,xr,krcei,linestyle=0,psym=0,thick=3
   ;
   ; annotate model results and CEI specs
   xlabpos1 = xr[0] + 0.95*(xr[1] - xr[0])
   xlabpos2 = xr[0] + 0.05*(xr[1] - xr[0])
   ylabpos1 = krmod[0] + 0.015
   ylabpos2 = krcei[0] + 0.015
   lab1     = 'Synphot model prediction'
   lab2     = 'CEI spec. (10.0% @ 1216 Angstroms - opt. bench level)'
   xyouts,xlabpos1,ylabpos1,lab1,alignment=1.0
   xyouts,xlabpos2,ylabpos2,lab2,alignment=0.0

END